СИМВОЛИ КОДОВОЇ ТАБЛИЦІ ASCII 3 страница
вiдкривається iснуючий файл, в даному випадку Inputa.out, як для читання так і для запису, що є відміністю в порівнянні з текстовим файлом.
Команда
Rewrite (f2);
створює новий файл Inputa.out й відкриває його як для запису так і для читання. Якщо файл із ім’ям Inputa.out вже iснує, то його вмiст знищується.
Команди читання Read, Readlnта запису Write,Writelnінформації у файл, а також закриття файлу Close використовуються аналогічно як і для розглянутих вище текстових файлів.
Всі елементи типізованого файлу пронумеровані, починаючи з нуля. Для прямого доступу до будь-якого елементу файлу, тобто для читання чи запису конкретного елементу, потрібно попередньо встановити вказівник файлу на потрібну позицію за допомогою команди
Seek (f2, 7);
В даному випадку вказівник встановлено у сьому позицію, тобто на восьмий елемент файлу.
Для визначення кількості елементів у типізованому файлі служить функція цілочисленого типу longint
FileSize (f2),
а для визначення поточної позиції вказівника файла – функція того ж типу
FilePos (f2).
1.5. При вирішенні деяких задач потрібно зчитати всі елементи у текстовому чи типізованому файлі або в окремому рядку, проте кількість елементів невідома. Для цього корисно використовувати функції логічного типу
Eof(f)таEoln(f).
Перша функція повертає значення True (істина), якщо вказівник файлу знаходиться в кінці файлу, а друга – якщо в кінці рядка.
1.6. Приклад 1.Створити новий типізований файл Inputa.txt та записати до нього до 20 випадкових цілих чисел. Зчитати дані з цього файлу та відсортувати їх на збільшення. Відсортований масив вивести на екран та дописати в кінець існуючого текстового файлу Outputa.txt, розділивши існуючі дані вільним рядком.
Program _File;
Uses Crt;
Var
Masiv :array [1..20] of word;
I, Imax, J, X :word;
f1 :file of word;
f2 :text;
Begin
TextBackGround (blue);
ClrScr;
TextColor (yellow);
{
Створення файлу Inputa.txt та заповнення його випадковою кількістю випадкових цілих чисел
}
Assign (f1, 'Inputa.txt');
Rewrite (f1);
Randomize;
Imax:=Random (20);
for I:=1 to Imax do
begin
J:=Random (777);
Write (f1, J);
end;
Close (f1);
{
Читання з файлу Inputa.txt невідомої
кількості елементів даних
}
Assign (f1, 'Inputa.txt');
Reset (f1);
I:=1;
While Not Eof(f1) do
begin
Read (f1, Masiv[I]);
I:=I+1;
end;
Close (f1);
{
Сортування елементів даних
кількістю Imax на збільшення
}
Imax:=I-1;
For I:=2 to Imax do
for J:=Imax downto I do
if Masiv[J-1] > Masiv[J] then
begin
X:=Masiv[J-1];
Masiv[J-1]:=Masiv[J];
Masiv[J]:=X;
end;
{
Запис відсортованих даних у файл
Outputa.txt та вивід їх на екран
}
Assign (f2, 'Outputa.txt');
Append (f2);
Writeln (f2);
For I:=1 to Imax do
begin
Writeln (f2,Masiv[I]);
Writeln (Masiv[I]);
end;
Close (f2);
Readln;
End.
2. ЗАВДАННЯ НА РОБОТУ
Розробити та запустити у роботу програму на мові програмування "Паскаль", яка вирішує задачу відповідно до заданого нижче варіанта. При цьому детально вивчити та практично застосувати пункт меню Options інтегрованого середовища мови.
2.1. Створити новий типізований файл, ім’я якого вводиться з клавіатури, та заповнити його 29 випадковими цілими числами. Прочитати і відобразити на екрані 1, 8, 15, 22, 29 елементи файлу та знайти серед них найменший. Результат з відповідним повідомленням записати в новий текстовий файл DATA.OUT та вивести на екран.
2.2. Створити новий текстовий файл DATA.IN та заповнити його 22 випадковими дійсними числами в проміжку від 9 до 125. Прочитати і відобразити на екрані перші 11 елементів файлу та знайти серед них найбільший. Результат дописати в кінець даного файлу з відповідним повідомленням та вивести на екран.
2.3. Обчислити значення функції Y=A*sin(В*X) при зміні Х від 0 до 3 з кроком 0,05. Значення Х та Y в форматі з фіксованою крапкою та з відповідним заголовком вивести в два стовпця на екран та записати в текстовий файл, імя якого задається з клавіатури. Значення параметрів А та В взяти з попередньо створеного текстового файлу ЕРА.ТХТ.
2.4. Знайти мінімальні елементи кожного стовпця дійсної матриці А3х4, яка знаходиться в попередньо створеному текстовому файлі ЕР.DАТ. Результат з відповідним повідомленням записати в новий текстовий файл ЕР.ОUТ та вивести на екран.
2.5. Створити новий типізований файл IN.DAT та записати до нього масив дійсних чисел, кількість елементів якого вводиться з клавіатури. Отримати новий масив шляхом додавання до поточних елементів масиву найменшого елементу. Результат дописати в кінець існуючого текстового файлу OUT.DAT.
2.6. Створити новий типізований файл EPA.DAT та заповнити його випадковими цілими числами. Прочитати і відобразити на екрані перший та останній елементи файлу та знайти серед них найбільший. Результат з відповідним повідомленням записати в новий текстовий файл EPA.OUT та вивести на екран.
2.7. Створити новий текстовий файл DATA.IN та заповнити його 35 випадковими дійсними числами. Прочитати і відобразити на екрані останні 9 елементів файлу та знайти серед них найменший. Результат дописати в кінець даного файлу з відповідним повідомленням та вивести на екран.
2.8. Обчислити значення функції Y=B*соs(C* X) при зміні Х від 1 до 5 з кроком 0,1. Значення Х та Y в форматі з фіксованою крапкою та з відповідним заголовком вивести в два стовпця на екран та записати в текстовий файл ЕРА .IN. Значення параметрів B та C взяти з текстового файлу ЕРА.ТХТ.
2.9. Знайти максимальні елементи кожного рядку цілочисленої матриці С4x4, яка знаходиться в текстовому файлі ЕР.DАТ. Результат з відповідним повідомленням записати в новий текстовий файл, ім’я якого задається з клавіатури, та вивести на екран.
2.10. Створити новий типізований файл ЕР.DАТ та записати до нього масив з 25 цілих чисел. Створити новий масив шляхом множення поточних елементів масиву на перший елемент. Результат дописати в кінець існуючого текстового файлу OUT.DAT.
3. КОНТРОЛЬНІ ЗАПИТАННЯ
3.1. Які види файлів підтримує мова програмування "Паскаль".
3.2. Яка послідовність роботи з файлами.
3.3. Як описуються файлові змінні для різних видів файлів.
3.4. Якими командами відкриваються файли для запису та читання інформації.
3.5. За допомогою яких команд здійснюється читання та запис інформації до файлу.
Комп'ютерний практикум № 6
ПОБУДОВА ГРАФІКІВ ФУНКЦІЙ НА МОВІ "ПАСКАЛЬ"
Мета практикуму – розробка програмного забезпечення на мові програмування "Паскаль" із засобами відображення на екрані дисплея залежностей у вигляді графіків функцій.
1. ТЕОРЕТИЧНІ ВІДОМОСТІ
1.1. Побудова на екрані графіків функцій здійснюється при роботі дисплея у графічному режимі, коли програмісту доступна кожна точка (pixel – піксель) екрана. Кількість точок по ширині та висоті екрана визначає його роздільну здатність, наприклад, 640х480. При цьому лівий верхній кут екрана має координату (0,0), рис. 1.1. Значення координат по осі Х та Y повинно бути цілочисленого типу.
Роздільність екрана визначається не тільки характеристикою дисплея, а й типом його відеоадаптера (відеокарти). Найбільш популярним є тип VGA, який підтримує три графічні режими, табл. 1.1.
Таблиця 1.1.
Тип адаптера | Графічний режим | Роздільність екрана |
VGA | VGALo (або цифра 0) VGAMed (або цифра 1) VGAHi (або цифра 2) | 640x200 640x350 640x480 |
1.2. Команди мови "Паскаль" для роботи у графічному режимі дисплея знаходяться в стандартному бібліотечному модулі Graph, тому його необхідно підключити в описуючій частині програми
Uses Graph;
Бібліотечний графічний модуль Graphзберігається в окремому файлі Graph.tpu
1.3. При роботі комп’ютера під керуванням операційної системи DOS дисплей автоматично встановлюється у текстовий режим, тому для переходу для роботи у графічному режимі його потрібно ініціювати у виконавчій частині програми за допомогою процедури
InitGraph (<тип графічного драйвера :integer>,
<графічний режим :integer>, <шлях до драйвера :string>);
для якої необхідно вказати наступні три параметри:
1) Тип графічного драйвера записується буквами чи цифрами в залежності від типу дисплея, наприклад, для найбільш поширених драйверів це такі значення: VGAабо цифра9, EGAабо цифра3, CGAабо цифра1. Для автоматичного визначення необхідного типу драйвера корисно використовувати функцію Detect;
2) Графічний режим за згодою забезпечує максимальну роздільність екрана. Якщо її потрібно зменшити, наприклад, для адаптера VGA, то значення режиму задається буквами чи цифрами відповідно до табл. 1.1;
3) Шлях до драйвера записується в апострофах з указуванням диска та каталогів. Якщо вони не вказуються, то пошук драйвера буде здійснюватися в поточному каталозі. Графічні драйвери зберігаються у файлах із розширенням .BGI, наприклад файл EGAVGA.BGI. Найчастіше всі драйвери знаходяться у підкаталозі BGI, що входить до каталогу програмних засобів мови "Паскаль".
1.4 Після завершення роботи у графічному режимі його потрібно обов'язково закрити процедурою CloseGraph;
1.5. Внутрішні помилки в модулі Graphзберігаються у функції GraphResult, значення яких використовуються для вирішення задачі коректного запуску графічного режиму дисплея. Коди помилок приймають значення від мінус одиниці до мінус 14, опис яких можна отримати у пункті меню Help. При відсутності помилок функція приймає значення нуль, яке ще позначається символами gkOk.
1.6. У графічному режимі за типом курсору на екрані існує невидимий вказівник розміром у піксель, який позначається СР (current pointer). При відкритті графічного режиму СР встановлюється у лівий верхній кут екрана, а потім переміщується при виконанні операцій виводу на екран. Встановлення вказівника в задану позицію на екрані, наприклад, в координати (х=200, у=100) здійснюється командою
MoveTo (200, 100);
1.7. Для побудови графіків та координатних сіток використовуються три команди малювання ліній.
З’єднання прямою лінією двох точок на екрані з координатами (х1=100, у1=50) та (х2=200, у2=150) здійснюється командою
Line (100, 50, 200, 150);
Лінія від вказівника до точки, наприклад, із координатами (х=250, у=150) малюється командою
LineTo (250, 150);
Цю команду зручно використовувати для виводу одного графіка.
Лінія в приростах від координат вказівника, наприклад, для приростів Dх=50, Dу=100, будується командою
LineRel (50, 100);
1.8. Колір ліній задається цифрами від нуля до 15 або словами від black (чорний) до white(білий), тобто як для текстового режиму. Наприклад, блакитний колір (blue) установлюється за допомогою команди
SetColor (blue);
За згодою встановлено білий колір ліній.
Колір фону екрана, наприклад, червоний, задається командою
SetBkColor (red);
За згодою встановлено чорний колір фону.
1.9. Товщина та тип лінії встановлюються процедурою
SetLineStyle (<тип, шаблон, товщина:word>);
Тип лінії можна задавати словами чи цифрами відповідно до табл. 1.1.
Табл.1.1.
Тип лінії | Примітка |
SolidLn (або цифра 0) | Суцільна лінія |
DottedLn (або цифра 1) | Лінія з точок |
CenterLn (або цифра 2) | Штрих-пунктирна лінія |
DashedLn (або цифра 3) | Штрихова лінія |
UserBitLn (або цифра 4) | Тип лінії задає користувач |
Перші чотири типи є стандартними й для них значення шаблону задається рівним нулю. Є також можливість створювати свій тип лінії, задавши значення типу рівним чотири (UserBitLn). В цьому випадку шаблон записується 16-ма бітами, яким відповідає 16 пікселів ділянки лінії. Біт рівний одиниці, означає, що піксель світиться, а рівний нулю – не світиться. Комбінуючи ці біти, можна створити заданий тип лінії. Наприклад, усім одиничним бітам, тобто 1111111111111111, відповідає суцільна лінія. Значення бітів можна задавати й у шістнадцятковому коді, наприклад, для суцільної лінії $FFFF.
Лінія може бути нормальної товщини чи жирною. Товщина задається командами згідно з таблицею 1.2.
Табл.1.2.
Товщина | Примітка |
NormWidth (або цифра 1) | Нормальна товщина |
ThickWidth (або цифра 3) | Жирна лінія |
За згодою встановлена суцільна лінія нормальної товщини, тобто
SetLineStyle (0,0,1);
1.10. Для виводу текстової інформації на екран у графічному режимі можна скористатися однією з двох команд
OutText (’Текст для виводу’);
та
OutTextXY (200,100,’Текст для виводу’);
Перша команда виводить інформацію відносно поточної позиції вказівника екрана, а друга – відносно заданої позиції вказівника, в наведеному прикладі – це координати (х=200, у=100).
Недоліком представлених команд виводу є те, що вони дозволяють виводити інформацію тільки рядкового типу string, проте часто необхідно виводити на екран числові значення змінних. Для виходу із ситуації числові дані попередньо перетворюються у рядкові за допомогою процедури
Str (<число>,<рядковий еквівалент>);
наприклад, числове значення змінної Minдійсного типу realпередається змінній Sminрядкового типу string, а потім виводиться
Min:=10.3;
Str (Min,SMin);
OutText (Smin);
Текст може виводитися різними шрифтами та заданою величиною (розміром), які вказуються у команді
SetTextStyle (<шрифт, орієнтація тексту, розмір:word>);
Кожен шрифт зберігається в окремому файлі з розширенням .CHRнайчастіше у підкаталозі BGI, що входить до каталогу програмних засобів. Параметри команди задаються словами чи еквівалентними цифрами. Позначення стандартних шрифтів мови "Паскаль" представлено в табл.1.3.
Табл.1.3.
Тип шрифту | Примітка |
DefaultFont (або цифра 0) | Растровий шрифт, матриця 8х8 |
TriplexFont (або цифра 1) | Штриховий напівжирний шрифт |
SmallFont (або цифра 2) | Штриховий тонкий шрифт |
SansSerifFont (або цифра 3) | Штриховий рублений шрифт |
GothicFont (або цифра 5) | Штриховий готичний шрифт |
Текст може виводитися горизонтально – зліва направо чи вертикально – знизу догори. Орієнтація задається командами згідно табл. 1.4.
Табл.1.4.
Орієнтація тексту | Примітка |
HorizDir (або цифра 0) | Горизонтально |
VertDir (або цифра 1) | Вертикально |
Розмір шрифту встановлюється цифрами в межах від нуля до 10, причому нульове значення відповідає стандартному розміру шрифту.
За згодою встановлено растровий шрифт стандартного розміру, направлений горизонтально, тобто
SetTextStyle (0,0,0);
Вирівнювання тексту на екрані відносно позиції вказівника СР (точки виводу) здійснюється процедурою
SetTextJustify (<по горизонталі, по вертикалі:word>);
Вирівнювання задається командами у вигляді слів чи еквівалентних цифр відповідно до табл.1.5.
Табл.1.5.
Вирівнювання | Примітка |
По горизонталі | |
LeftText (або цифра 0) | Вказівник ліворуч тексту |
CenterText (або цифра 1) | Вказівник по центру тексту |
RightText (або цифра 2) | Вказівник праворуч тексту |
По вертикалі | |
BottomText (або цифра 0) | Вказівник вище тексту |
CenterText (або цифра 1) | Вказівник по центру тексту |
TopText (або цифра 2) | Вказівник нище тексту |
За згодою встановлено вирівнювання по центру, тобто
SetTextJustify (1,1);
1.11. Для ефективної роботи програми з будь-яким драйвером та роздільністю екрана необхідно обчислювати координати точок на екрані відносно поточної роздільності. Для цього використовуються функції
GetMaxXта GetMaxY
цілочисленого типу word, які повертають роздільність екрана по координаті X та Y відповідно.
1.12. На екран можна виводити точку заданого кольору в задану позицію, що інколи використовується для побудови графіка. Наприклад, вивід зеленої точки в позицію з координатами (х=150, у=50) виконується командою
PutPixel (150,50,green);
1.13. Очистка екрана у графічному режимі здійснюється командою
ClearDevice;
1.14. При побудові графіків потрібно враховувати протилежний до математичного напрямок осі Y на екрані, рис. 1.1. Позиція точки по осі Y визначається різницею між максимальним розмахом координатної сітки графіка та обчисленою координатою точки Y0. Наприклад, якщо координатна сітка займає весь екран по осі Y, то координата дорівнює
Y:= GetMaxY – Y0;
Обчислення координат точок для виводу графіків на основі реальних координат Xd та Yd здійснюється з урахуванням їх цілочисленого типу й масштабів по осях X та Y
X0:= Round(Xd*Mx);
Y0:= Round(Yd*My);
Масштаби визначаються максимальним реальним значенням функції Ymaxй аргументу Xmax, а також максимальним розмахом координатної сітки графіка по осях. Наприклад, якщо координатна сітка займає весь екран, то масштаби дорівнюють
Mx:= GetMaxX/Xmax;
My:= GetMaxY/Ymax;
1.15. Приклад 1. Розрахувати значення та побудувати графік функції при зміні аргументу t від нуля до 2 з кроком 0,01 для наступних значень параметрів: А=5; a=-1,5; w=30; y=1,8. Програма складається з двох підпрограм-процедур: Function_W та Graphic. Підпрограма Function_W обчислює значення заданої функції й визначає її максимальне та мінімальне значення, які потім використовуються для визначення масштабу по осі Y при побудові графіка функції. Обчислені значення функції та аргументу виводяться на екран та записуються до файлу. Друга підпрограма Graphicбудує на екрані координатну сітку та графік на основі значень функції записаних у файл. На екран виводяться також екстремальні значення функції та аргументу для чого використовується підпрограма-функція RealToStr,що перетворює дані дійсного типу в рядкові.
Program Graphica;
Uses Graph, Crt;
Const
Tend=2; t:real=0;
Var
W, Wmax, Wmin :real;
f :text;
grDriver, grMode, errCode :integer;
Procedure Function_W;
Const
A=5;
alpha=-1.5;
omega=30;
ksi=1.8;
dt=0.01;
Begin
TextBackGround (lightgray);
ClrScr;
TextColor (red);
Writeln ('РОЗРАХУНОК ЗНАЧЕНЬ ФУНКЦІЇ');
Writeln;
TextColor (black);
Writeln (' ':2,'Аргумент',' ':6,'Функція');
Window (1,4,80,25);
TextColor (white);
Assign (f,'F:\TP\Data.Out');
Rewrite (f);
Wmax:=-10E10;
Wmin:=10E10;
Repeat
W:=A*Exp(alpha*t)*Sin(omega*t+ksi);
Writeln (' ':3, t:5:2,' ':7,W:7:2);
Writeln (f, t:5:2,W:7:2);
If W>Wmax then Wmax:=W;
If W<Wmin then Wmin:=W;
t:=t+dt;
Delay (5);
Until t>Tend+dt;
Readln;
Window (1,1,80,25);
Close (f);
End;
Procedure Graphic (x1,y1,x2,y2:word);
Const
N=4;
M=4;
Var
X, Yw, X0, Yw0, J :integer;
Mt, Mw, Wmod :real;
Function RealToStr (R :real) :string;
Var
S :string;
Begin
Str (R:7:2, S);
RealToStr:= S;
End;
Begin
SetBkColor(red);
SetFillStyle (1, lightgray);
Bar (x1, y1, x2, y2);
For J:=0 to N do Line (((x2-x1) div N+1)*J+x1, y1,
((x2-x1) div N+1)*J+x1, y2);
For J:=0 to M do Line (x1, ((y2-y1) div M+1)*J+y1,
x2, ((y2-y1) div M+1)*J+y1);
SetTextJustify (CenterText, CenterText);
SetTextStyle (SmallFont, HorizDir, 5);
OutTextXY (x1-5, ((y2-y1) div 2)+y1, '0');
OutTextXY (x2+7, ((y2-y1) div 2)+y1, 'T');
OutTextXY (x1-5, y1, 'W');
SetColor (yellow);
SetLineStyle (0,0,3);
If (Wmax>=0) and (Wmin<0) then Wmod:=Wmax+Abs(Wmin);
If (Wmax>=0) and (Wmin>0) then Wmod:=Wmax;
If (Wmax<0) and (Wmin<=0) then Wmod:=Abs(Wmin);
Mt:=(x2-x1)/Tend;
Mw:=(y2-y1)/Wmod;
Assign (f, 'F:\TP\Data.out');
Reset (f);
Readln (f, t,W);
X0:=x1+Round (t*Mt);
Yw0:=y2-((y2-y1) div 2)-Round (W*Mw);
While Not Eof (f) do
begin
Readln (f, t,W);
X:=x1+Round (t*Mt);
Yw:=Y2-((Y2-Y1) div 2)-Round (W*Mw);
Line (X0,Yw0,X,Yw);
X0:=X;
Yw0:=Yw;
end;
Close (f);
SetColor (red);
OutTextXY (x2-210, y2-80, 'Tend='+RealToStr(t));
SetColor (green);
OutTextXY (x2-210, y2-60, 'Wmax='+RealToStr (Wmax));
SetColor (magenta);
OutTextXY (x2-210, y2-40, 'Wmin='+RealToStr (Wmin));
Repeat until KeyPressed;
end;
BEGIN
Function_W;
grDriver:= Detect;
InitGraph (grDriver, grMode,'F:\TP\BGI');
errCode:= GraphResult;
if errCode <> grOk then
begin
Writeln (GraphErrorMsg(ErrCode));
Halt;
end;
Graphic (30, 30, GetMaxX-30, GetMaxY-30);
CloseGraph;
END.
2. ЗАВДАННЯ НА РОБОТУ
Розробити та запустити у роботу програму на мові програмування "Паскаль", яка вирішує задачу відповідно до заданого нижче варіанта.
2.1. Обчислити значення та побудувати графіки функцій Y1=А*sin(В*х+рі/3) та Y2=С*(1-е-x) при зміні аргументу Х від нуля до 5 з кроком 0,05. Значення коефіцієнтів А, В, С ввести з клавіатури. Значення аргументу та функцій вивести в три стовпці на екран із відповідними заголовками та записати у файл. Графіки вивести в першу четверть екрана на одну координатну сітку різним кольором. Підписати координатні осі та вивести максимальні значення функцій та аргументу.
2.2. Обчислити значення та побудувати графіки функцій Y=С*e-x +А*(1-е-х) та Z=В*соs(х+рі/4) при зміні аргументу Х від нуля до 3 з кроком 0,01. Значення коефіцієнтів А, В, С задати у вигляді констант. Значення аргументу та функцій вивести в три стовпці на екран з відповідними заголовками та записати у файл. Графіки вивести в третю четверть екрана на одну координатну сітку різним кольором. Підписати координатні осі та вивести максимальні значення функцій.
2.З. Обчислити значення та побудувати графіки функцій Y=А*sin(В*х) та F=С+(1-е-x) при зміні аргументу Х від нуля до 7 із кроком 0,05. Значення коефіцієнтів А, В, С ввести з клавіатури. Значення аргументу та функцій вивести в три стовпці на екран з відповідними заголовками та записати у файл. Графіки вивести в другу четверть екрана на одну координатну сітку різним кольором. Підписати координатні осі та вивести максимальні значення функцій та аргументу.
2.4. Обчислити значення та побудувати графіки функцій Z=А –B*(1-е-x) та Y=С*соs(х-рі/6) при зміні аргументу Х від нуля до 10 з кроком 0,04. Значення коефіцієнтів А, В, С задати у вигляді констант. Значення аргументу та функцій вивести в три стовпці на екран з відповідними заголовками та записати у файл. Графіки вивести в другу четверть екрана на одну координатну сітку різним кольором. Підписати координатні осі та вивести максимальні значення функцій та аргументу.
2.5. Обчислити значення та побудувати графіки функцій Y2=А*(1-е-x) та Z3=В*sin(С*х-рі/3) при зміні аргументу Х від нуля до 6 з кроком 0,01. Значення коефіцієнтів А, В, С задати у вигляді констант. Значення аргументу та функцій вивести в три стовпці на екран з відповідними заголовками та записати у файл. Графіки вивести на весь екран на одну координатну сітку різним кольором. Підписати координатні осі та вивести максимальні значення функцій.
2.6. Обчислити значення та побудувати графіки функцій Y1=А*e-x +В*(1-е-x) та Z=С*cos(х+рі/З) при зміні аргументу Х від нуля до 8 з кроком 0,02. Значення коефіцієнтів А, В, С задати у вигляді констант. Значення аргументу та функцій вивести в три стовпці на екран з відповідними заголовками та записати у файл. Графіки вивести в третю четверть екрана на одну координатну сітку різним кольором. Підписати координатні осі та вивести максимальні значення функцій.
2.7. Обчислити значення та побудувати графіки функцій Y=А*sin(В*х+рі/5) та Z=C*(1-е-x) при зміні аргументу Х від нуля до 6 з кроком 0,02. Значення коефіцієнтів А, В, С ввести з клавіатури. Значення аргументу та функцій вивести в три стовпці на екран з відповідними заголовками та записати у файл. Графіки вивести в другу четверть екрана на одну координатну сітку різним кольором. Підписати координатні осі та вивести максимальні значення функцій та аргументу.
2.8. Обчислити значення та побудувати графіки функцій Z1=А –В*(1-е-x) та Z2=С*соs(х+рі/4) при зміні аргументу Х від нуля до 5 з кроком 0,01. Значення коефіцієнтів А, В, С задати у вигляді констант. Значення аргументу та функцій вивести в три стовпці на екран з відповідними заголовками та записати у файл. Графіки вивести в другу четверть екрана на одну координатну сітку різним кольором. Підписати координатні осі та вивести максимальні значення функцій та аргументу.
2.9. Обчислити значення та побудувати графіки функцій Y2=А*(1-е-х)+В та Z1=С*sin(х-рі/3) при зміні аргументу Х від нуля до 6 з кроком 0,01. Значення коефіцієнтів А, В, С задати у вигляді констант. Значення аргументу та функцій вивести в три стовпці на екран з відповідними заголовками та записати у файл. Графіки вивести на весь екран на одну координатну сітку різним кольором. Підписати координатні осі та вивести максимальні значення функцій.